dev-games/openscenegraph: 3.6.5 version bump

Closes: https://bugs.gentoo.org/709878
Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 151 insertions, 0 deletions

diff --git a/dev-games/openscenegraph/Manifest b/dev-games/openscenegraph/Manifest
index 6651e63277c5..9cb2176a3d3b 100644
--- a/dev-games/openscenegraph/Manifest
+++ b/dev-games/openscenegraph/Manifest
@@ -1,2 +1,3 @@
 DIST OpenSceneGraph-3.5.5.tar.gz 5666085 BLAKE2B f474f7e62476c816cc9b036995f2571e65d33ed426a95eb2727994fd2c46e95457bf5392e488556e53c13c30bd46250f0c3d871678a4de234eae8953c03560a6 SHA512 f4a890bfbabab0ed8d50ad50e8f9ae5aa6edd4a73eda30d6c53ad478889608f7c980306a79549ca1e472cdd3df8061af03537c8139fa6446b00aebf47ec26827
 DIST OpenSceneGraph-3.6.4.tar.gz 5771539 BLAKE2B 3f608566ed8bd927f30c18ab25147826a40655bfa0eca2b0765f775d1fca53c090b77c9963b392bb73b405150f64f1b3bdc57ac6ef59de7f88bf9fd208b2ff6e SHA512 7cb34fc279ba62a7d7177d3f065f845c28255688bd29026ffb305346e1bb2e515a22144df233e8a7246ed392044ee3e8b74e51bf655282d33ab27dcaf12f4b19
+DIST OpenSceneGraph-3.6.5.tar.gz 5780762 BLAKE2B 31ebeeae94eb6aff043788313946d5c08886f97d97cd5796e600918e137ef7f06839206b79b2f5649aac7f34037d4d79e18a5638152e150de931b7f7a7d3c38b SHA512 7002fa30a3bcf6551d2e1050b4ca75a3736013fd190e4f50953717406864da1952deb09f530bc8c5ddf6e4b90204baec7dbc283f497829846d46d561f66feb4b
diff --git a/dev-games/openscenegraph/openscenegraph-3.6.5.ebuild b/dev-games/openscenegraph/openscenegraph-3.6.5.ebuild
new file mode 100644
index 000000000000..658788ad51a8
--- /dev/null
+++ b/dev-games/openscenegraph/openscenegraph-3.6.5.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="OpenSceneGraph"
+MY_P=${MY_PN}-${PV}
+WX_GTK_VER="3.0"
+inherit cmake flag-o-matic wxwidgets
+
+DESCRIPTION="Open source high performance 3D graphics toolkit"
+HOMEPAGE="http://www.openscenegraph.org/"
+SRC_URI="https://github.com/${PN}/${MY_PN}/archive/${MY_P}.tar.gz"
+
+LICENSE="wxWinLL-3 LGPL-2.1"
+SLOT="0/160" # NOTE: CHECK WHEN BUMPING! Subslot is SOVERSION
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="asio curl dicom debug doc egl examples ffmpeg fltk fox gdal gif glut
+gstreamer jpeg las libav lua openexr openinventor osgapps pdf png sdl sdl2
+svg tiff truetype vnc wxwidgets xrandr +zlib"
+
+REQUIRED_USE="sdl2? ( sdl ) dicom? ( zlib ) openexr? ( zlib )"
+
+# TODO: COLLADA, FBX, GTA, NVTT, OpenVRML, Performer
+BDEPEND="
+	app-arch/unzip
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="
+	media-libs/mesa[egl?]
+	virtual/glu
+	virtual/opengl
+	x11-libs/libSM
+	x11-libs/libXext
+	asio? ( dev-cpp/asio )
+	curl? ( net-misc/curl )
+	examples? (
+		fltk? ( x11-libs/fltk:1[opengl] )
+		fox? ( x11-libs/fox:1.6[opengl] )
+		glut? ( media-libs/freeglut )
+		sdl2? ( media-libs/libsdl2 )
+		wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[opengl,X] )
+	)
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	gdal? ( sci-libs/gdal:= )
+	gif? ( media-libs/giflib:= )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	jpeg? ( virtual/jpeg:0 )
+	las? ( >=sci-geosciences/liblas-1.8.0 )
+	lua? ( >=dev-lang/lua-5.1.5:* )
+	openexr? (
+		media-libs/ilmbase:=
+		media-libs/openexr:=
+	)
+	openinventor? ( media-libs/coin )
+	pdf? ( app-text/poppler[cairo] )
+	png? ( media-libs/libpng:0= )
+	sdl? ( media-libs/libsdl )
+	svg? (
+		gnome-base/librsvg
+		x11-libs/cairo
+	)
+	tiff? ( media-libs/tiff:0 )
+	truetype? ( media-libs/freetype:2 )
+	vnc? ( net-libs/libvncserver )
+	xrandr? ( x11-libs/libXrandr )
+	zlib? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+
+S="${WORKDIR}/${MY_PN}-${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.6.3-cmake.patch
+	"${FILESDIR}"/${PN}-3.6.3-docdir.patch
+)
+
+src_configure() {
+	if use examples && use wxwidgets; then
+		need-wxwidgets unicode
+	fi
+
+	# Needed by FFmpeg
+	append-cppflags -D__STDC_CONSTANT_MACROS
+
+	local libdir=$(get_libdir)
+	local mycmakeargs=(
+		-DDYNAMIC_OPENSCENEGRAPH=ON
+		-DLIB_POSTFIX=${libdir/lib}
+		-DOPENGL_PROFILE=GL2 #GL1 GL2 GL3 GLES1 GLES3 GLES3
+		-DOSG_ENVVAR_SUPPORTED=ON
+		-DOSG_PROVIDE_READFILE=ON
+		-DOSG_USE_LOCAL_LUA_SOURCE=OFF
+		$(cmake_use_find_package asio Asio)
+		$(cmake_use_find_package curl CURL)
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		$(cmake_use_find_package dicom DCMTK)
+		$(cmake_use_find_package egl EGL)
+		-DBUILD_OSG_EXAMPLES=$(usex examples)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package gdal GDAL)
+		$(cmake_use_find_package gif GIFLIB)
+		$(cmake_use_find_package gstreamer GLIB)
+		$(cmake_use_find_package gstreamer GStreamer)
+		-DCMAKE_DISABLE_FIND_PACKAGE_GtkGl=ON
+		$(cmake_use_find_package jpeg JPEG)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Jasper=ON
+		$(cmake_use_find_package las LIBLAS)
+		$(cmake_use_find_package lua Lua51)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Lua52=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_OpenCascade=ON
+		$(cmake_use_find_package openexr OpenEXR)
+		$(cmake_use_find_package openinventor Inventor)
+		-DBUILD_OSG_APPLICATIONS=$(usex osgapps)
+		$(cmake_use_find_package pdf Poppler-glib)
+		$(cmake_use_find_package png PNG)
+		$(cmake_use_find_package sdl SDL)
+		$(cmake_use_find_package sdl2 SDL2)
+		$(cmake_use_find_package svg RSVG)
+		$(cmake_use_find_package tiff TIFF)
+		$(cmake_use_find_package truetype Freetype)
+		$(cmake_use_find_package vnc LibVNCServer)
+		-DOSGVIEWER_USE_XRANDR=$(usex xrandr)
+		$(cmake_use_find_package zlib ZLIB)
+	)
+	if use examples; then
+		mycmakeargs+=(
+			$(cmake_use_find_package fltk FLTK)
+			$(cmake_use_find_package fox FOX)
+			$(cmake_use_find_package glut GLUT)
+			$(cmake_use_find_package wxwidgets wxWidgets)
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile doc_openscenegraph doc_openthreads
+}