dev-java/classmate: version bump.

Signed-off-by: Patrice Clement <monsieurp@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.10

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-java/classmate/classmate-1.2.0.ebuild b/dev-java/classmate/classmate-1.2.0.ebuild
new file mode 100644
index 000000000000..5b084f9f2a6c
--- /dev/null
+++ b/dev-java/classmate/classmate-1.2.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Zero-dependency Java library for accurately introspecting type information"
+HOMEPAGE="https://github.com/cowtowncoder/java-classmate/"
+SRC_URI="https://github.com/cowtowncoder/java-classmate/archive/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=virtual/jre-1.6"
+
+DEPEND="
+	>=virtual/jdk-1.6
+	test? ( dev-java/junit:4 )"
+
+S="${WORKDIR}/java-${PN}-${P}"
+
+JAVA_SRC_DIR="src/main/java"
+
+src_prepare() {
+	default
+	rm -v pom.xml \
+		src/test/java/com/fasterxml/classmate/AnnotationsTest.java || die
+}
+
+src_test() {
+	testcp="${S}/${PN}.jar:$(java-pkg_getjars junit-4):target/tests"
+
+	mkdir target/tests || die
+	ejavac -cp "${testcp}" -d target/tests $(find src/test/java -name "*.java")
+
+	tests=$(find target/tests -name "*Test.class" -not -name "BaseTest.class" \
+			| sed -e 's/target\/tests\///g' -e "s/\.class//" -e "s/\//./g" \
+			| grep -vP '\$');
+	ejunit4 -cp "${testcp}" ${tests}
+}