dev-java/jettison: Rewrite for version bump to 1.3.7

Update HOMEPAGE and SRC_URI as Codehaus has gone. Java version bump to
6 removes dependency on jaxp-virtual.

Package-Manager: portage-2.2.20.1

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-java/jettison/jettison-1.3.7.ebuild b/dev-java/jettison/jettison-1.3.7.ebuild
new file mode 100644
index 000000000000..01b414bcdba2
--- /dev/null
+++ b/dev-java/jettison/jettison-1.3.7.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="A JSON StAX implementation"
+HOMEPAGE="https://github.com/codehaus/jettison"
+SRC_URI="https://github.com/codehaus/${PN}/archive/${P}.tar.gz"
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x86-solaris"
+IUSE="test"
+
+RDEPEND=">=virtual/jre-1.6"
+
+DEPEND=">=virtual/jdk-1.6
+	test? (
+		dev-java/junit:4
+		dev-java/wstx:3.2 )"
+
+S="${WORKDIR}/${PN}-${P}"
+JAVA_SRC_DIR="${S}/src/main/java"
+
+src_test() {
+	cd src/test/java || die
+	local CP=".:${S}/${PN}.jar:$(java-pkg_getjars junit-4,wstx-3.2)"
+
+	local TESTS=$(find * -name "*Test.java" ! -name "DOMTest.java")
+	TESTS="${TESTS//.java}"
+	TESTS="${TESTS//\//.}"
+
+	ejavac -classpath "${CP}" $(find -name "*.java")
+	ejunit4 -classpath "${CP}" ${TESTS}
+}