dev-lang/duktape: Fix header install

Closes: https://bugs.gentoo.org/729914
Closes: https://bugs.gentoo.org/729840
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Ian Whyman <thev00d00@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-lang/duktape/duktape-2.5.0-r1.ebuild b/dev-lang/duktape/duktape-2.5.0-r1.ebuild
new file mode 100644
index 000000000000..096bdf229105
--- /dev/null
+++ b/dev-lang/duktape/duktape-2.5.0-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Embeddable Javascript engine"
+HOMEPAGE="https://duktape.org"
+SRC_URI="https://duktape.org/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64  ~ppc ~ppc64 ~x86"
+IUSE=""
+
+DEPEND=""
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	eapply_user
+
+	# Set install path
+	sed -i "s#INSTALL_PREFIX = /usr/local#INSTALL_PREFIX = ${D%/}/usr#" \
+			Makefile.sharedlibrary || die "failed to set install path"
+
+	# Edit pkgconfig
+	sed "s#VERSION#${PV}#" "${FILESDIR}/${PN}.pc" > "${S}/${PN}.pc" || die
+	sed -i "s#LIBDIR#$(get_libdir)#" "${S}/${PN}.pc" || die
+
+	# Set lib folder
+	sed -i "s#(INSTALL_PREFIX)/lib#(INSTALL_PREFIX)/$(get_libdir)#" \
+		Makefile.sharedlibrary || die
+
+	mv Makefile.sharedlibrary Makefile || die "failed to rename makefile"
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	dodir /usr/$(get_libdir)
+	dodir /usr/include
+	emake install
+
+	insinto /usr/$(get_libdir)/pkgconfig/
+	doins "${S}/${PN}.pc"
+}