dev-libs/kreport: 3.2.0 version bump

Package-Manager: Portage-2.3.63, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-libs/kreport/kreport-3.2.0.ebuild b/dev-libs/kreport/kreport-3.2.0.ebuild
new file mode 100644
index 000000000000..b47441c3979b
--- /dev/null
+++ b/dev-libs/kreport/kreport-3.2.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_QTHELP="true"
+KDE_TEST="true"
+PYTHON_COMPAT=( python2_7 python3_{6,7} )
+VIRTUALX_REQUIRED="test"
+inherit kde5 python-any-r1
+
+DESCRIPTION="Framework for creation and generation of reports in multiple formats"
+[[ ${KDE_BUILD_TYPE} != live ]] && SRC_URI="mirror://kde/stable/${PN}/src/${P}.tar.xz"
+
+LICENSE="LGPL-2+"
+SLOT="5/4"
+KEYWORDS="~amd64 ~x86"
+IUSE="marble +scripting webkit"
+
+RDEPEND="
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtprintsupport)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	>=dev-libs/kproperty-3.1.0:5=
+	marble? ( $(add_kdeapps_dep marble '' '' '5=') )
+	scripting? ( $(add_qt_dep qtdeclarative) )
+	webkit? ( >=dev-qt/qtwebkit-5.212.0_pre20180120:5 )
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	kde5_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package marble Marble)
+		$(cmake-utils_use_find_package webkit Qt5WebKitWidgets)
+		-DKREPORT_SCRIPTING=$(usex scripting)
+	)
+	kde5_src_configure
+}