dev-libs/libdnet: drop 1.14-r1

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 0 insertions, 77 deletions

diff --git a/dev-libs/libdnet/libdnet-1.14-r1.ebuild b/dev-libs/libdnet/libdnet-1.14-r1.ebuild
deleted file mode 100644
index 921313b5d730..000000000000
--- a/dev-libs/libdnet/libdnet-1.14-r1.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-AT_M4DIR="config"
-PYTHON_COMPAT=( python3_{7,8,9} )
-DISTUTILS_OPTIONAL=1
-inherit autotools distutils-r1
-
-DESCRIPTION="simplified, portable interface to several low-level networking routines"
-HOMEPAGE="https://github.com/ofalk/libdnet"
-SRC_URI="https://github.com/ofalk/${PN}/archive/${P}.tar.gz"
-S="${WORKDIR}/${PN}-${P}"
-
-LICENSE="LGPL-2"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86"
-IUSE="python static-libs test"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-RESTRICT="test"
-
-DEPEND="python? ( ${PYTHON_DEPS} )"
-RDEPEND="${DEPEND}"
-
-DOCS=( README.md THANKS TODO )
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.14-ndisc.patch
-	"${FILESDIR}"/${PN}-1.14-strlcpy.patch
-)
-
-src_prepare() {
-	default
-
-	sed -i \
-		-e 's/libcheck.a/libcheck.so/g' \
-		-e 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' \
-		configure.ac || die
-	sed -i \
-		-e 's|-L$libdir ||g' \
-		dnet-config.in || die
-	sed -i \
-		-e '/^SUBDIRS/s|python||g' \
-		Makefile.am || die
-
-	eautoreconf
-
-	if use python; then
-		cd python || die
-		distutils-r1_src_prepare
-	fi
-}
-
-src_configure() {
-	econf \
-		$(use_with python) \
-		$(use_enable static-libs static)
-}
-
-src_compile() {
-	default
-	if use python; then
-		cd python || die
-		distutils-r1_src_compile
-	fi
-}
-
-src_install() {
-	default
-	if use python; then
-		cd python || die
-		unset DOCS
-		distutils-r1_src_install
-	fi
-	find "${ED}" -name '*.la' -delete || die
-}