dev-libs/libowfat: Fix compile with GCC 10 for www-servers/gatling

Closes: https://bugs.gentoo.org/756847
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-3.0.0, Repoman-2.3.23

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-libs/libowfat/libowfat-0.32-r2.ebuild b/dev-libs/libowfat/libowfat-0.32-r2.ebuild
new file mode 100644
index 000000000000..6e711f600ef4
--- /dev/null
+++ b/dev-libs/libowfat/libowfat-0.32-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="reimplement libdjb - excellent libraries from Dan Bernstein"
+SRC_URI="https://www.fefe.de/${PN}/${P}.tar.xz"
+HOMEPAGE="https://www.fefe.de/libowfat/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~sparc ~x86"
+IUSE="diet"
+
+RDEPEND="diet? ( >=dev-libs/dietlibc-0.33_pre20090721 )"
+DEPEND="${RDEPEND}
+	>=sys-apps/sed-4"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc10.patch
+)
+
+pkg_setup() {
+	# Required for mult/umult64.c to be usable
+	append-flags -fomit-frame-pointer
+}
+
+src_compile() {
+	emake \
+		CC=$(tc-getCC) \
+		CFLAGS="-I. ${CFLAGS}" \
+		DIET="${EPREFIX}/usr/bin/diet -Os" \
+		prefix="${EPREFIX}/usr" \
+		INCLUDEDIR="${EPREFIX}/usr/include" \
+		$( use diet || echo 'DIET=' )
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		MAN3DIR="${EPREFIX}/usr/share/man/man3" \
+		INCLUDEDIR="${EPREFIX}/usr/include" \
+		install
+
+	mv "${ED}"/usr/share/man/man3/{buffer.3,owfat-buffer.3} || die
+}