dev-libs/libtasn1: Revbump to not install fuzzer tool anymore

Thanks-to: Arfrever Frehtes Taifersar Arahesis <arfrever.fta@gmail.com>
Closes: https://bugs.gentoo.org/701928
Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-libs/libtasn1/libtasn1-4.15.0-r1.ebuild b/dev-libs/libtasn1/libtasn1-4.15.0-r1.ebuild
new file mode 100644
index 000000000000..e3e7c7a51749
--- /dev/null
+++ b/dev-libs/libtasn1/libtasn1-4.15.0-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal libtool
+
+DESCRIPTION="ASN.1 library"
+HOMEPAGE="https://www.gnu.org/software/libtasn1/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3 LGPL-2.1"
+SLOT="0/6" # subslot = libtasn1 soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc static-libs test valgrind"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="sys-apps/help2man
+	virtual/yacc
+	test? ( valgrind? ( dev-util/valgrind ) )"
+
+DOCS=(
+	AUTHORS
+	ChangeLog
+	NEWS
+	README.md
+	THANKS
+)
+
+PATCHES=(
+	"${FILESDIR}"/${P}-noinst_fuzzer_tool.patch #701928
+)
+
+pkg_setup() {
+	if use doc; then
+		DOCS+=( doc/libtasn1.pdf )
+		HTML_DOCS=( doc/reference/html/. )
+	fi
+}
+
+src_prepare() {
+	default
+	#elibtoolize  # for Solaris shared library
+	eautoreconf #701928
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable static-libs static) \
+		$(multilib_native_use_enable valgrind valgrind-tests)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -type f -name '*.la' -delete || die
+}