dev-libs/libuv: Version 1.39.0

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-libs/libuv/libuv-1.39.0.ebuild b/dev-libs/libuv/libuv-1.39.0.ebuild
new file mode 100644
index 000000000000..a9a8ca340c4c
--- /dev/null
+++ b/dev-libs/libuv/libuv-1.39.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib-minimal
+
+DESCRIPTION="Cross-platform asychronous I/O"
+HOMEPAGE="https://github.com/libuv/libuv"
+SRC_URI="https://github.com/libuv/libuv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD BSD-2 ISC MIT"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+RESTRICT="test"
+
+BDEPEND="
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	echo "m4_define([UV_EXTRA_AUTOMAKE_FLAGS], [serial-tests])" \
+		> m4/libuv-extra-automake-flags.m4 || die
+
+	# upstream fails to ship a configure script
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		cc_cv_cflags__g=no
+		$(use_enable static-libs static)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_test() {
+	mkdir "${BUILD_DIR}"/test || die
+	cp -pPR "${S}"/test/fixtures "${BUILD_DIR}"/test/fixtures || die
+	default
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -delete || die
+}