dev-libs/libxdg-basedir: Version bump 1.2.3.

Signed-off-by: Ronny (tastytea) Gutbrod <gentoo@tastytea.de>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-libs/libxdg-basedir/libxdg-basedir-1.2.3.ebuild b/dev-libs/libxdg-basedir/libxdg-basedir-1.2.3.ebuild
new file mode 100644
index 000000000000..54e64709c907
--- /dev/null
+++ b/dev-libs/libxdg-basedir/libxdg-basedir-1.2.3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Small library to access XDG Base Directories Specification paths"
+HOMEPAGE="https://github.com/devnev/libxdg-basedir"
+SRC_URI="https://github.com/devnev/libxdg-basedir/archive/${P}.tar.gz"
+S="${WORKDIR}/${PN}-${P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x64-macos ~x86-solaris"
+IUSE="doc"
+
+BDEPEND="doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		$(use_enable doc doxygen-html)
+}
+
+src_compile() {
+	emake
+
+	if use doc; then
+		emake doxygen-doc
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	use doc && local HTML_DOCS=( doc/html/. )
+	einstalldocs
+
+	find "${ED}" -type f -name '*.la' -delete
+}