proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 74 insertions, 0 deletions

diff --git a/dev-libs/m17n-lib/m17n-lib-1.6.4.ebuild b/dev-libs/m17n-lib/m17n-lib-1.6.4.ebuild
new file mode 100644
index 000000000000..dc1c05e06e47
--- /dev/null
+++ b/dev-libs/m17n-lib/m17n-lib-1.6.4.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+inherit eutils autotools
+
+DESCRIPTION="Multilingual Library for Unix/Linux"
+HOMEPAGE="https://savannah.nongnu.org/projects/m17n"
+SRC_URI="http://download.savannah.gnu.org/releases/m17n/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="anthy athena anthy bidi fontconfig gd spell libotf libxml2 X xft"
+
+RDEPEND="
+	anthy? ( app-i18n/anthy )
+	spell? ( app-text/aspell )
+	libxml2? ( dev-libs/libxml2 )
+	X? (
+		athena? ( x11-libs/libXaw )
+		bidi? ( dev-libs/fribidi )
+		fontconfig? ( media-libs/fontconfig )
+		gd? ( media-libs/gd[png] )
+		libotf? ( >=dev-libs/libotf-0.9.4 )
+		xft? (
+			>=media-libs/freetype-2.1
+			x11-libs/libXft )
+		x11-libs/libX11
+	)
+	~dev-db/m17n-db-${PV}"
+# athena? ( x11-libs/libXaw )
+# athena shoud be enabled to build m17n-edit properly when X is enabled.
+
+# linguas_th? ( || ( app-i18n/libthai app-i18n/wordcut ) )
+#
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-1.6.2-gui.patch \
+		"${FILESDIR}"/${PN}-1.6.3-parallel-make.patch \
+		"${FILESDIR}"/${PN}-1.6.3-configure.patch \
+		"${FILESDIR}"/${PN}-1.6.3-ispell.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf="$(use_with anthy) $(use_with spell ispell) $(use_with libxml2)"
+
+	if use X; then
+		myconf+=" --with-x --enable-gui $(use_with athena) $(use_with bidi fribidi)
+$(use_with fontconfig) $(use_with xft freetype) $(use_with gd) $(use_with libotf)
+$(use_with xft)"
+	else
+		myconf+=" --without-x --disable-gui --without-athena --without-fribidi
+--without-fontconfig --without-freetype --without-gd --without-libotf
+--without-xft"
+	fi
+
+	econf ${myconf} || die
+}
+
+src_install() {
+	# bug #363239
+	emake -j1 DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog NEWS README TODO
+}