dev-libs/rocm-device-libs: Bump to 4.1.0

Mix of different versions can cause spurious build failures.
This brings it to same version with llvm-roc etc.

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Patrick Lauer <patrick@gentoo.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-libs/rocm-device-libs/rocm-device-libs-4.1.0.ebuild b/dev-libs/rocm-device-libs/rocm-device-libs-4.1.0.ebuild
new file mode 100644
index 000000000000..94bddf83d919
--- /dev/null
+++ b/dev-libs/rocm-device-libs/rocm-device-libs-4.1.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/RadeonOpenCompute/ROCm-Device-Libs/"
+	inherit git-r3
+	S="${WORKDIR}/${P}/src"
+else
+	SRC_URI="https://github.com/RadeonOpenCompute/ROCm-Device-Libs/archive/rocm-${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/ROCm-Device-Libs-rocm-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Radeon Open Compute Device Libraries"
+HOMEPAGE="https://github.com/RadeonOpenCompute/ROCm-Device-Libs"
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1-2)"
+
+RDEPEND=">=sys-devel/llvm-roc-${PV}:="
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	sed -e "s:amdgcn/bitcode:lib/amdgcn/bitcode:" -i "${S}/cmake/OCL.cmake" || die
+	sed -e "s:amdgcn/bitcode:lib/amdgcn/bitcode:" -i "${S}/cmake/Packages.cmake" || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLLVM_DIR="${EPREFIX}/usr/lib/llvm/roc/lib/cmake/llvm"
+	)
+	cmake_src_configure
+}