dev-libs/rocm-opencl-driver: 2.7.0 version bump

Package-Manager: Portage-2.3.71, Repoman-2.3.17
Signed-off-by: Craig Andrews <candrews@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-libs/rocm-opencl-driver/rocm-opencl-driver-2.7.0.ebuild b/dev-libs/rocm-opencl-driver/rocm-opencl-driver-2.7.0.ebuild
new file mode 100644
index 000000000000..f95628a7cb79
--- /dev/null
+++ b/dev-libs/rocm-opencl-driver/rocm-opencl-driver-2.7.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/RadeonOpenCompute/ROCm-OpenCL-Driver/"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/RadeonOpenCompute/ROCm-OpenCL-Driver/archive/roc-${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/ROCm-OpenCL-Driver-roc-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Radeon Open Compute OpenCL Compiler Tool Driver"
+HOMEPAGE="https://github.com/RadeonOpenCompute/ROCm-OpenCL-Driver"
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1-2)"
+IUSE="test"
+
+RDEPEND=">=sys-devel/llvm-roc-${PV}:=
+	>=dev-libs/rocr-runtime-${PV}"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.6.0-install-correctly.patch"
+	"${FILESDIR}/${PN}-2.6.0-install-header.patch"
+)
+
+src_prepare() {
+	# remove unittest, because it downloads additional file from github.com
+	sed -e "s:add_subdirectory(src/unittest):#add_subdirectory(src/unittest):" -i CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLLVM_DIR="${EPREFIX}/usr/lib/llvm/roc/"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr/"
+	)
+	cmake-utils_src_configure
+}