dev-libs/sord: fixed compilation with gcc10 + added live

Closes: https://bugs.gentoo.org/726312
Package-Manager: Portage-3.0.5, Repoman-3.0.1
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

1 files changed, 61 insertions, 0 deletions

diff --git a/dev-libs/sord/sord-0.16.4-r1.ebuild b/dev-libs/sord/sord-0.16.4-r1.ebuild
new file mode 100644
index 000000000000..2c0d0b7cfc2e
--- /dev/null
+++ b/dev-libs/sord/sord-0.16.4-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE='threads(+)'
+inherit python-any-r1 waf-utils multilib-build multilib-minimal
+
+DESCRIPTION="Library for storing RDF data in memory"
+HOMEPAGE="http://drobilla.net/software/sord/"
+SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~sparc x86"
+IUSE="doc static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/libpcre
+	>=dev-libs/serd-0.30.0
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig"
+
+DOCS=( "AUTHORS" "NEWS" "README.md" )
+
+PATCHES=(
+	"${FILESDIR}/${P}-gcc10.patch"
+)
+
+src_prepare() {
+	sed -i -e 's/^.*run_ldconfig/#\0/' wscript || die
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	waf-utils_src_configure \
+		--docdir=/usr/share/doc/${PF} \
+		$(multilib_native_usex doc --docs "") \
+		$(usex test --test "") \
+		$(usex static-libs --static "")
+}
+
+multilib_src_test() {
+	./waf test || die
+}
+
+multilib_src_compile() {
+	waf-utils_src_compile
+	default
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+	default
+}