dev-libs/appstream: add 1.0.3

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/dev-libs/appstream/Manifest b/dev-libs/appstream/Manifest
index 460e8ece43db..ffb182456db6 100644
--- a/dev-libs/appstream/Manifest
+++ b/dev-libs/appstream/Manifest
@@ -1,2 +1,3 @@
 DIST AppStream-0.16.4.tar.xz 2570176 BLAKE2B ac051b846fd1c7b0cbb3429e0b4c3f81027cddb35ee6bcd5e9d38a09d937abcc37ac4908f68ec55404ae852fd146b4e749832d3ac96443458e86cfe506a6fed4 SHA512 e3a9fc423fe5a2baaaa002871566f320ecd6dbd3a01ab24221afe9b93a69e9afb6bed6d7772c434376501803dc7b2c80b79eda849fcaf4748f9f24a5908a22a8
 DIST AppStream-1.0.2.tar.xz 2629708 BLAKE2B eb31e675cea1c8b9357227c851bdd24f9cb949e232089380a8727630ab8055f0de6bebd74f70f3c1cf84e5420b9d4fef681671a0e4e97265af26d594b2874c48 SHA512 e5c109c383e3bf3af3693bfb3146663767c2c61fac0bd421f2ce52242fe7b869effeacc4d207987321dfeb4ab0ba77ece6c1c6eea054a7365204cd955426517a
+DIST AppStream-1.0.3.tar.xz 2644220 BLAKE2B cd7aa28b49c23229ee48b9a69e57a08244f81115e23525695e463930d2296daf80b5c7bb098c89726c220caec8c3e072fd85d77ac808e96c5cf2ff0488ba4ba1 SHA512 9b70d965966d55dbcc6a62d85525fdd5990a28abb1d94b2df91ab1549c24ce9c40d95e2d761c2f24e0c61fe5b74ab6a1f829dda387a8282aa9dff9198dc9610d
diff --git a/dev-libs/appstream/appstream-1.0.3.ebuild b/dev-libs/appstream/appstream-1.0.3.ebuild
new file mode 100644
index 000000000000..e59ebce431a1
--- /dev/null
+++ b/dev-libs/appstream/appstream-1.0.3.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg-utils
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ximion/${PN}"
+else
+	MY_PN="AppStream"
+	SRC_URI="https://www.freedesktop.org/software/appstream/releases/${MY_PN}-${PV}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
+HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+# check as_api_level
+SLOT="0/5"
+IUSE="apt doc +introspection qt6 systemd test"
+RESTRICT="test" # bug 691962
+
+RDEPEND="
+	app-arch/zstd:=
+	>=dev-libs/glib-2.62:2
+	dev-libs/libxml2:2
+	>=dev-libs/libxmlb-0.3.14:=
+	dev-libs/libyaml
+	dev-libs/snowball-stemmer:=
+	>=net-misc/curl-7.62
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+	qt6? ( dev-qt/qtbase:6 )
+	systemd? ( sys-apps/systemd:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/libxslt
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	doc? ( app-text/docbook-xml-dtd:4.5 )
+	test? ( dev-qt/qttools:6[linguist] )
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.0.0-disable-Werror-flags.patch ) # bug 733774
+
+src_prepare() {
+	default
+	sed -e "/^as_doc_target_dir/s/appstream/${PF}/" -i docs/meson.build || die
+	if ! use test; then
+		sed -e "/^subdir.*tests/s/^/#DONT /" -i {,qt/}meson.build || die # bug 675944
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+
+	local emesonargs=(
+		-Dapidocs=false
+		-Ddocs=false
+		-Dcompose=false
+		-Dmaintainer=false
+		-Dstatic-analysis=false
+		-Dstemming=true
+		-Dvapi=false
+		-Dapt-support=$(usex apt true false)
+		-Dinstall-docs=$(usex doc true false)
+		-Dgir=$(usex introspection true false)
+		-Dqt=$(usex qt6 true false)
+		-Dsystemd=$(usex systemd true false)
+	)
+
+	meson_src_configure
+}