dev-libs/opensc: fix test search path for softhsm, disable broken

These tests are currently getting run only when dev-libs/softhsm is
installed, BUT on some architectures (including amd64), they use the
wrong search path (we install in /usr/$(get_libdir)/softhsm) and thus
think it's not installed anyway and skip.

Firstly, this commit enables these tests by overriding the search path.
However, one of the tests is broken (all architectures).  This seems to
be at least partially known upstream as there is a long trail of commits
disabling it for each individual release tag; but upstream seems to
recently have stopped disabling it for unknown reasons.  Given the
flakiness, disable this specific test downstream.

Bug: https://bugs.gentoo.org/909781
Signed-off-by: Matoro Mahri <matoro_gentoo@matoro.tk>
Closes: https://github.com/gentoo/gentoo/pull/35737
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 105 insertions, 12 deletions

diff --git a/dev-libs/opensc/opensc-0.25.0-r1.ebuild b/dev-libs/opensc/opensc-0.25.0-r1.ebuild
new file mode 100644
index 000000000000..5546950912e9
--- /dev/null
+++ b/dev-libs/opensc/opensc-0.25.0-r1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools bash-completion-r1
+
+DESCRIPTION="Libraries and applications to access smartcards"
+HOMEPAGE="https://github.com/OpenSC/OpenSC/wiki"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/OpenSC/OpenSC.git"
+else
+	SRC_URI="https://github.com/OpenSC/OpenSC/releases/download/${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0/11"
+IUSE="ctapi doc openct notify pace +pcsc-lite readline secure-messaging ssl test zlib"
+RESTRICT="!test? ( test )"
+
+RDEPEND="zlib? ( sys-libs/zlib )
+	readline? ( sys-libs/readline:0= )
+	ssl? ( dev-libs/openssl:0= )
+	openct? ( >=dev-libs/openct-0.5.0 )
+	pace? ( dev-libs/openpace:= )
+	pcsc-lite? ( >=sys-apps/pcsc-lite-1.3.0 )
+	notify? ( dev-libs/glib:2 )"
+DEPEND="${RDEPEND}
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	test? (
+		dev-util/cmocka
+		dev-libs/softhsm
+	)"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	pcsc-lite? ( !openct !ctapi )
+	openct? ( !pcsc-lite !ctapi )
+	ctapi? ( !pcsc-lite !openct )
+	|| ( pcsc-lite openct ctapi )"
+
+src_prepare() {
+	# This test is known to fail, for a long time upstream has carried
+	# version-specific patches which they would update on every version bump.
+	# There doesn't appear to be a permanent solution yet.
+	sed -i "/test-pkcs11-tool-unwrap-wrap-test.sh/d" "tests/Makefile.am" || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# don't want to run upstream's clang-tidy checks
+	export ac_cv_path_CLANGTIDY=""
+
+	econf \
+		--with-completiondir="$(get_bashcompdir)" \
+		--disable-strict \
+		--enable-man \
+		$(use_enable ctapi) \
+		$(use_enable doc) \
+		$(use_enable notify) \
+		$(use_enable openct) \
+		$(use_enable pace openpace) \
+		$(use_enable pcsc-lite pcsc) \
+		$(use_enable readline) \
+		$(use_enable secure-messaging sm) \
+		$(use_enable ssl openssl) \
+		$(use_enable test cmocka) \
+		$(use_enable zlib)
+}
+
+src_test() {
+	P11LIB="/usr/$(get_libdir)/softhsm/libsofthsm2.so" default
+}
+
+src_install() {
+	default
+
+	insinto /etc/pkcs11/modules/
+	doins "${FILESDIR}"/opensc.module
+
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/dev-libs/opensc/opensc-9999.ebuild b/dev-libs/opensc/opensc-9999.ebuild
index a470c4913c37..5546950912e9 100644
--- a/dev-libs/opensc/opensc-9999.ebuild
+++ b/dev-libs/opensc/opensc-9999.ebuild
@@ -1,23 +1,23 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-inherit bash-completion-r1 libtool
+inherit autotools bash-completion-r1
 
 DESCRIPTION="Libraries and applications to access smartcards"
 HOMEPAGE="https://github.com/OpenSC/OpenSC/wiki"
 
 if [[ ${PV} == *9999 ]]; then
-	inherit autotools git-r3
+	inherit git-r3
 	EGIT_REPO_URI="https://github.com/OpenSC/OpenSC.git"
 else
 	SRC_URI="https://github.com/OpenSC/OpenSC/releases/download/${PV}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~ppc64 ~x86"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 fi
 
 LICENSE="LGPL-2.1"
-SLOT="0"
+SLOT="0/11"
 IUSE="ctapi doc openct notify pace +pcsc-lite readline secure-messaging ssl test zlib"
 RESTRICT="!test? ( test )"
 
@@ -31,7 +31,10 @@ RDEPEND="zlib? ( sys-libs/zlib )
 DEPEND="${RDEPEND}
 	app-text/docbook-xsl-stylesheets
 	dev-libs/libxslt
-	test? ( dev-util/cmocka )"
+	test? (
+		dev-util/cmocka
+		dev-libs/softhsm
+	)"
 BDEPEND="virtual/pkgconfig"
 
 REQUIRED_USE="
@@ -41,13 +44,12 @@ REQUIRED_USE="
 	|| ( pcsc-lite openct ctapi )"
 
 src_prepare() {
+	# This test is known to fail, for a long time upstream has carried
+	# version-specific patches which they would update on every version bump.
+	# There doesn't appear to be a permanent solution yet.
+	sed -i "/test-pkcs11-tool-unwrap-wrap-test.sh/d" "tests/Makefile.am" || die
 	default
-
-	if [[ ${PV} == *9999 ]]; then
-		eautoreconf
-	else
-		elibtoolize
-	fi
+	eautoreconf
 }
 
 src_configure() {
@@ -71,6 +73,10 @@ src_configure() {
 		$(use_enable zlib)
 }
 
+src_test() {
+	P11LIB="/usr/$(get_libdir)/softhsm/libsofthsm2.so" default
+}
+
 src_install() {
 	default