dev-lua/lua-zlib: migrate to lua eclass

Closes: https://bugs.gentoo.org/752630
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-lua/lua-zlib/lua-zlib-1.2-r100.ebuild b/dev-lua/lua-zlib/lua-zlib-1.2-r100.ebuild
new file mode 100644
index 000000000000..51adad6b25f7
--- /dev/null
+++ b/dev-lua/lua-zlib/lua-zlib-1.2-r100.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+
+inherit cmake lua
+
+DESCRIPTION="Simple streaming interface to zlib for Lua"
+HOMEPAGE="https://github.com/brimworks/lua-zlib"
+SRC_URI="https://github.com/brimworks/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}"
+
+lua_src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_CMOD="$(lua_get_cmod_dir)"
+		-DUSE_LUA_VERSION="$(lua_get_version)"
+	)
+
+	if [[ ${ELUA} == luajit ]]; then
+		mycmakeargs+=( -DUSE_LUAJIT="ON" )
+	fi
+
+	cmake_src_configure
+}
+
+src_configure() {
+	lua_foreach_impl lua_src_configure
+}
+
+src_compile() {
+	lua_foreach_impl cmake_src_compile
+}
+
+src_install() {
+	lua_foreach_impl cmake_src_install
+}