dev-ml/zarith: bump to 1.4.1

Package-Manager: portage-2.2.24
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-ml/zarith/zarith-1.4.1.ebuild b/dev-ml/zarith/zarith-1.4.1.ebuild
new file mode 100644
index 000000000000..6c958607ea7e
--- /dev/null
+++ b/dev-ml/zarith/zarith-1.4.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit findlib eutils toolchain-funcs
+
+DESCRIPTION="Arithmetic and logic operations over arbitrary-precision integers"
+HOMEPAGE="https://forge.ocamlcore.org/projects/zarith/"
+SRC_URI="https://forge.ocamlcore.org/frs/download.php/1574/${P}.tgz"
+
+LICENSE="LGPL-2.1-with-linking-exception"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="doc mpir +ocamlopt"
+
+RDEPEND="
+	>=dev-lang/ocaml-4:=[ocamlopt?]
+	!mpir? ( dev-libs/gmp:0= )
+	mpir? ( sci-libs/mpir )"
+
+DEPEND="${RDEPEND} dev-lang/perl"
+
+src_configure() {
+	tc-export CC
+	./configure -host "${CHOST}" \
+		-ocamllibdir "/usr/$(get_libdir)" \
+		-installdir "${ED}/usr/$(get_libdir)/ocaml" \
+		$(usex mpir "-mpir" "-gmp") || die
+}
+
+src_compile() {
+	emake HASOCAMLOPT=$(usex ocamlopt yes no) HASDYNLINK=$(usex ocamlopt yes no) all
+	use doc && emake doc
+}
+
+src_test() {
+	emake HASOCAMLOPT=$(usex ocamlopt yes no) HASDYNLINK=$(usex ocamlopt yes no) tests
+}
+
+src_install() {
+	findlib_src_preinst
+	emake HASOCAMLOPT=$(usex ocamlopt yes no) HASDYNLINK=$(usex ocamlopt yes no) install
+	dodoc Changes README
+	use doc && dohtml html/*
+}