dev-perl/Video-ivtv: EAPI6 + tests

- EAPI6ify
- Add rudimentary tests
- Add "I'm an adult" features to force test

Package-Manager: Portage-2.3.24, Repoman-2.3.6

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-perl/Video-ivtv/Video-ivtv-0.13-r2.ebuild b/dev-perl/Video-ivtv/Video-ivtv-0.13-r2.ebuild
new file mode 100644
index 000000000000..7d62cb7029de
--- /dev/null
+++ b/dev-perl/Video-ivtv/Video-ivtv-0.13-r2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit perl-module
+
+DESCRIPTION="Video::ivtv perl module, for use with ivtv-ptune"
+HOMEPAGE="http://ivtv.sourceforge.net"
+SRC_URI="mirror://sourceforge/ivtv/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND=""
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	export OPTIMIZE="$CFLAGS"
+	perl-module_src_configure
+}
+
+# Requires /dev/video0 access, set DIST_TEST_OVERRIDE
+# to circumvent
+DIST_TEST="skip"
+
+src_test() {
+	ebegin "Compile testing Video::ivtv ${PV}"
+		perl -Mblib="${S}" -M"Video::ivtv ${PV} ()" -e1
+	if ! eend $?; then
+		echo
+		eerror "One or more modules failed compile:";
+		eerror "  Video::ivtv ${PV}"
+		die "Failing due to module compilation errors";
+	fi
+	perl-module_src_test
+}