dev-python/Kivy: Version bump, add py3.5 support

* EAPI=6
* Also fix overlong DESCRIPTION

Package-Manager: portage-2.3.0

1 files changed, 69 insertions, 0 deletions

diff --git a/dev-python/Kivy/Kivy-1.9.1.ebuild b/dev-python/Kivy/Kivy-1.9.1.ebuild
new file mode 100644
index 000000000000..670d58448df7
--- /dev/null
+++ b/dev-python/Kivy/Kivy-1.9.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DESCRIPTION="Library for rapid development of hardware-accelerated multitouch applications"
+HOMEPAGE="http://kivy.org/"
+SRC_URI="https://pypi.io/packages/source/${PN:0:1}/${PN}/${P,,}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cairo camera doc examples garden gstreamer +sdl spell test"
+
+RDEPEND="
+	dev-python/pillow[${PYTHON_USEDEP}]
+	cairo? ( dev-python/pycairo[${PYTHON_USEDEP}] )
+	camera? ( media-libs/opencv )
+	garden? ( dev-python/kivy-garden[${PYTHON_USEDEP}] )
+	gstreamer? ( dev-python/gst-python:1.0[${PYTHON_USEDEP}] )
+	sdl? ( media-libs/libsdl2
+		media-libs/sdl2-ttf
+		media-libs/sdl2-image
+		media-libs/sdl2-mixer )
+	!sdl? ( dev-python/pygame[${PYTHON_USEDEP}] )
+	spell? ( dev-python/pyenchant[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${P,,}"
+
+python_prepare_all() {
+	sed -e '/data_files=/d' -i "${S}/setup.py" || die
+	sed -e 's/PYTHON = python/PYTHON ?= python/' -i Makefile || die
+
+	export USE_SDL2=$(usex sdl 1 0)
+	export USE_GSTREAMER=$(usex gstreamer 1 0)
+	export KIVY_USE_SETUPTOOLS=1
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	esetup.py build_ext --inplace
+	esetup.py build
+}
+
+python_compile_all() {
+	use doc && emake html
+}
+
+python_test() {
+	emake test PYTHON="${PYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( doc/build/html/. )
+	use examples && EXAMPLES=( examples )
+	distutils-r1_python_install_all
+}