dev-python/debugpy: add version 1.4.2

No keywords until I'm sure the unbundling hack doesn't produce any
unexpected side effects

Bug: https://bugs.gentoo.org/812041
Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-python/debugpy/debugpy-1.4.2.ebuild b/dev-python/debugpy/debugpy-1.4.2.ebuild
new file mode 100644
index 000000000000..1d2e0eec0d00
--- /dev/null
+++ b/dev-python/debugpy/debugpy-1.4.2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="An implementation of the Debug Adapter Protocol for Python"
+HOMEPAGE="https://github.com/microsoft/debugpy/ https://pypi.org/project/debugpy/"
+SRC_URI="https://github.com/microsoft/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+
+# There is not enough time in the universe for this test suite
+RESTRICT="test"
+
+BDEPEND="test? ( dev-python/pytest-timeout[${PYTHON_USEDEP}] )"
+
+RDEPEND="dev-python/pydevd[${PYTHON_USEDEP}]"
+
+PATCHES=(
+	"${FILESDIR}/${P}-unbundle-pydevd.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Drop unnecessary and unrecognized option
+	# __main__.py: error: unrecognized arguments: -n8
+	# Do not timeout
+	sed -i \
+		-e 's/-n8//g' \
+		-e '/timeout/d' \
+		pytest.ini || die
+
+	# Unbundle dev-python/pydevd
+	rm -r src/debugpy/_vendored || die
+
+	distutils-r1_python_prepare_all
+}