dev-python/deprecation: bump to 2.0.7, adds doc

Package-Manager: Portage-2.3.71, Repoman-2.3.16
Signed-off-by: Louis Sautier <sbraz@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/deprecation/deprecation-2.0.7.ebuild b/dev-python/deprecation/deprecation-2.0.7.ebuild
new file mode 100644
index 000000000000..7b4f8a12a278
--- /dev/null
+++ b/dev-python/deprecation/deprecation-2.0.7.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+DESCRIPTION="A library to handle automated deprecations"
+HOMEPAGE="https://deprecation.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/packaging[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/unittest2[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)
+"
+
+python_prepare_all() {
+	sed -i "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "tests failed with ${EPYTHON}"
+}