dev-python/docker-py: Version bump to 2.6.1

Package-Manager: Portage-2.3.14, Repoman-2.3.5

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/docker-py/docker-py-2.6.1.ebuild b/dev-python/docker-py/docker-py-2.6.1.ebuild
new file mode 100644
index 000000000000..559c7b0e68d7
--- /dev/null
+++ b/dev-python/docker-py/docker-py-2.6.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Docker"
+HOMEPAGE="https://github.com/docker/docker-py"
+SRC_URI="https://github.com/docker/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/docker-pycreds-0.2.1[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.12.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.11.1[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/backports-ssl-match-hostname-3.5[${PYTHON_USEDEP}]' 'python2_7' 'python3_4' )
+	$(python_gen_cond_dep '>=dev-python/ipaddress-1.0.16[${PYTHON_USEDEP}]' 'python2_7' )
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		>=dev-python/pytest-2.9.1[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/recommonmark[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.4.6[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	sed -i -e "s/import pip//" -e "s/if 'docker-py'.*/if False:/" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs html || die "docs failed to build"
+		HTML_DOCS=( html/. )
+	fi
+}
+
+python_test() {
+	py.test tests/unit/ || die "tests failed under ${EPYTHON}"
+}