dev-python/docker-py: 4.1.0 + EAPI 7

Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-2.3.84, Repoman-2.3.20

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/docker-py/docker-py-4.1.0.ebuild b/dev-python/docker-py/docker-py-4.1.0.ebuild
new file mode 100644
index 000000000000..ae65b322d32a
--- /dev/null
+++ b/dev-python/docker-py/docker-py-4.1.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_{6,7}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Docker"
+HOMEPAGE="https://github.com/docker/docker-py"
+SRC_URI="https://github.com/docker/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!~dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/backports-ssl-match-hostname-3.5[${PYTHON_USEDEP}]' 'python2_7' )
+	$(python_gen_cond_dep '>=dev-python/ipaddress-1.0.16[${PYTHON_USEDEP}]' 'python2_7' )
+"
+DEPEND="
+	test? (
+		${RDEPEND}
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/paramiko-2.4.2[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		>=dev-python/pytest-2.9.1[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/recommonmark[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.4.6[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs html || die "docs failed to build"
+		HTML_DOCS=( html/. )
+	fi
+}
+
+python_test() {
+	py.test tests/unit/ || die "tests failed under ${EPYTHON}"
+}