dev-python/gcs-oauth2-boto-plugin-2.5-r1: revbump, cleanups, py38

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/gcs-oauth2-boto-plugin/gcs-oauth2-boto-plugin-2.5-r1.ebuild b/dev-python/gcs-oauth2-boto-plugin/gcs-oauth2-boto-plugin-2.5-r1.ebuild
new file mode 100644
index 000000000000..071efa216aa5
--- /dev/null
+++ b/dev-python/gcs-oauth2-boto-plugin/gcs-oauth2-boto-plugin-2.5-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="OAuth 2.0 plugin for Google Cloud Storage credentials in the Boto library"
+HOMEPAGE="https://pypi.org/project/gcs-oauth2-boto-plugin/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.13-use-friendy-version-checks.patch"
+)
+
+# Keep versions in sync with setup.py.
+BDEPEND="
+	test? (	dev-python/freezegun[${PYTHON_USEDEP}] )
+"
+RDEPEND="${PYTHON_DEPS}
+	>=dev-python/boto-2.29.1[${PYTHON_USEDEP}]
+	dev-python/google-reauth-python[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.8[${PYTHON_USEDEP}]
+	>=dev-python/oauth2client-1.5.2[${PYTHON_USEDEP}]
+	!=dev-python/oauth2client-2.0*
+	>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+	>=dev-python/retry-decorator-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/PySocks-1.01[${PYTHON_USEDEP}]
+	>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	sed -e '/SocksiPy-branch/d' \
+		-i setup.py || die
+	# Make sure the unittests aren't installed.
+	mv gcs_oauth2_boto_plugin/test_oauth2_client.py ./ || die
+}
+
+python_test() {
+	"${EPYTHON}" "${S}"/test_oauth2_client.py -v \
+		|| die "tests failed with ${EPYTHON}"
+}