dev-python/google-api-core: Bump to 2.0.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-python/google-api-core/google-api-core-2.0.1.ebuild b/dev-python/google-api-core/google-api-core-2.0.1.ebuild
new file mode 100644
index 000000000000..6e1d986b70c6
--- /dev/null
+++ b/dev-python/google-api-core/google-api-core-2.0.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Core Library for Google Client Libraries"
+HOMEPAGE="https://github.com/googleapis/python-api-core/
+	https://googleapis.dev/python/google-api-core/latest/index.html"
+SRC_URI="https://github.com/googleapis/${PN//google/python}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P//google/python}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+	dev-python/googleapis-common-protos[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.25.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	<dev-python/requests-3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/grpcio-1.33.2[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/rsa[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install pytest
+
+EPYTEST_DESELECT=(
+	# TODO: package proto-plus
+	tests/unit/test_protobuf_helpers.py::test_field_mask_ignore_trailing_underscore
+	tests/unit/test_protobuf_helpers.py::test_field_mask_ignore_trailing_underscore_with_nesting
+)
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${D}" -name '*.pth' -delete || die
+}