dev-python/google-auth: version bump to 1.1.0

Package-Manager: Portage-2.3.13, Repoman-2.3.3

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-python/google-auth/google-auth-1.1.0.ebuild b/dev-python/google-auth/google-auth-1.1.0.ebuild
new file mode 100644
index 000000000000..64bf9f26fd10
--- /dev/null
+++ b/dev-python/google-auth/google-auth-1.1.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Google Authentication Library"
+HOMEPAGE="https://pypi.python.org/pypi/google-auth/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.0.5[${PYTHON_USEDEP}]
+	>=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
+	>=dev-python/six-1.6.1[${PYTHON_USEDEP}]
+	>=dev-python/cachetools-2.0.0[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# urllib3-1.16 raised MaxRetryError, not TransportError
+	sed -e 's:test_connection_error:_\0:' \
+		-e 's:test_request_with_timeout_failure:_\0:' \
+		-i tests/transport/compliance.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# delete stray files included in the tarball
+	find "${S}"/tests -name '*.pyc' -delete || die
+	py.test || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}