dev-python/hypothesis: Bump to 4.50.8

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-python/hypothesis/hypothesis-4.50.8.ebuild b/dev-python/hypothesis/hypothesis-4.50.8.ebuild
new file mode 100644
index 000000000000..3def9e851218
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-4.50.8.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8} pypy{,3} )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
+SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' 'python2*' pypy)
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-4.3[${PYTHON_USEDEP}]
+		!!<dev-python/typing-3.7.4.1
+	)
+"
+
+S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
+
+src_prepare() {
+	# avoid pytest-xdist dep for one test
+	sed -i -e 's:test_prints_statistics_given_option_under_xdist:_&:' \
+		tests/pytest/test_statistics.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local pyver=$(python_is_python3 && echo 3 || echo 2)
+	pytest -vv tests/cover tests/pytest tests/py${pyver} ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}