dev-python/icalendar: add python-dateutil to RDEPEND.

Closes: https://bugs.gentoo.org/664888
Package-Manager: Portage-2.3.40, Repoman-2.3.9

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-python/icalendar/icalendar-3.11.7-r1.ebuild b/dev-python/icalendar/icalendar-3.11.7-r1.ebuild
new file mode 100644
index 000000000000..015b5a6c7e04
--- /dev/null
+++ b/dev-python/icalendar/icalendar-3.11.7-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1
+
+MY_PN="collective-${PN}"
+
+DESCRIPTION="Package used for parsing and generating iCalendar files (RFC 2445)"
+HOMEPAGE="https://github.com/collective/icalendar"
+SRC_URI="mirror://pypi/i/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="doc test"
+DOCS="README.rst"
+
+RDEPEND="
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]"
+
+DEPEND="
+	${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (	dev-python/python-dateutil:0[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# reset conf.py to not read version from an installed instance
+	sed -e "s:pkg_resources.get_distribution('icalendar').version:'3.9.0':" \
+		-i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		pushd docs > /dev/null
+		emake text
+		popd > /dev/null
+		DOCS=( ${DOCS} docs/_build/text/*.txt )
+	fi
+}
+
+python_test() {
+	# From tox.ini
+	coverage run --source=src/icalendar --omit=*/tests/* --module \
+		pytest src/icalendar || die "test failed under ${EPYTHON}"
+}