dev-python/jaraco-text: bump to 3.2.0, add Python 3.8 support

Package-Manager: Portage-2.3.80, Repoman-2.3.19
Signed-off-by: Louis Sautier <sbraz@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-python/jaraco-text/jaraco-text-3.2.0.ebuild b/dev-python/jaraco-text/jaraco-text-3.2.0.ebuild
new file mode 100644
index 000000000000..af0f4eceead8
--- /dev/null
+++ b/dev-python/jaraco-text/jaraco-text-3.2.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{5,6,7,8}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Text utilities used by other projects by developer jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.text"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/jaraco-functools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/namespace-jaraco-2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/importlib_resources[${PYTHON_USEDEP}]' python{2_7,3_{5,6}})
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+
+python_test() {
+	# Override pytest options to skip flake8
+	PYTHONPATH=. pytest -vv --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+# https://wiki.gentoo.org/wiki/Project:Python/Namespace_packages#File_collisions_between_pkgutil-style_packages
+python_install() {
+	rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
+	# note: eclass may default to --skip-build in the future
+	distutils-r1_python_install --skip-build
+}