dev-python/jupyter_core: DISTUTILS_USE_SETUPTOOLS=rdepend

Signed-off-by: Mike Gilbert <floppym@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/jupyter_core/jupyter_core-4.6.1-r1.ebuild b/dev-python/jupyter_core/jupyter_core-4.6.1-r1.ebuild
new file mode 100644
index 000000000000..6f686d287886
--- /dev/null
+++ b/dev-python/jupyter_core/jupyter_core-4.6.1-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Core common functionality of Jupyter projects"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/traitlets[${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-github-alt[${PYTHON_USEDEP}] )
+	test? ( >=dev-python/ipython-4.0.1[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	py.test jupyter_core || die
+}