dev-python/kombu: Bump to version 4.6.3

Note that this ebuild drops python2_7 from PYTHON_COMPAT because
it was also dropped from the dev-python/pyro-4.76 ebuild.

Closes: https://bugs.gentoo.org/688728
Package-Manager: Portage-2.3.67, Repoman-2.3.16
Signed-off-by: Zac Medico <zmedico@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 09d6745729cf..5b94000e4921 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1,3 +1,4 @@
 DIST kombu-4.1.0.tar.gz 421875 BLAKE2B 636dab025883bc9465b28e7a6ab4249ae7d079cc57d33b1af8ce8633e12b85027ace9601475f9e2db1782d197f888476ce6006a2d5429e040ee8de0d1c86266c SHA512 fc104a3f974fabf090cc257b1a7623af6048f4630c6c2a9bb693fe69d77b6cdab36135a290a41056c1f854f61cce8fc2aa6b7880e9273581bfdfa162b5724861
 DIST kombu-4.2.1.tar.gz 423926 BLAKE2B 8566e3d81bd77c93982f54300e837e2aaac1d1fbfc716c87607fb83b86bc80148afc37b11145ee33ff3a6cef9fadb6178c370dc5b47c0774a56e6b08b6bf951e SHA512 a480444199aeee4e0048803a49ee85f2b348734eccf0e746189ea7db3787cb27baa89765a71cf88288ec7171252d55e13bc787641a543d3f91d6eb3d30c6a90c
 DIST kombu-4.4.0.tar.gz 435287 BLAKE2B c87154f5f8862af9e0381f1f4eda6016e5ed69605a39b682c9e648003adf4aa4ed8ebbe7f6dc38b293ab013d8f5e31bb732cf47cc4aab7738be7edaaa25ca750 SHA512 2f7bd71f848c7bba0643e47c43af79ae09373597bed86786e3a90f2acd69414583021e7f5544e47bf01f760b1fd9788e89e88a32cd22a3d74a34845b7917e10b
+DIST kombu-4.6.3.tar.gz 427754 BLAKE2B 0db078eb8d6afd18a5e9b48c970791d2c55c46f5f705e8e0737c8685c2415e1ca974594377a54764f744cc73ff607668ece3c0999b1a7dad6a259567ac1fd319 SHA512 35113c4f19fe6bf94c374477c89a629f565975a23c16a3cedefa8e0c2a800cabbaa8917d48f732cf28e89cd5430fe8408a3514e055b1858c216b6ea31b4c014a
diff --git a/dev-python/kombu/kombu-4.6.3.ebuild b/dev-python/kombu/kombu-4.6.3.ebuild
new file mode 100644
index 000000000000..24fd55a80594
--- /dev/null
+++ b/dev-python/kombu/kombu-4.6.3.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="https://pypi.org/project/kombu/ https://github.com/celery/kombu"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples mongodb msgpack redis sqs test yaml"
+
+# zookeeper backend support possible via dev-python/kazoo
+RDEPEND="
+	>=dev-python/py-amqp-2.5.0[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-3.0[${PYTHON_USEDEP}]
+	>=dev-python/pyro-4.76:4[${PYTHON_USEDEP}]
+	sqs? ( >=dev-python/boto3-1.4.4[${PYTHON_USEDEP}] )
+	msgpack? ( >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}] )
+	mongodb? ( >=dev-python/pymongo-3.0.2[${PYTHON_USEDEP}] )
+	redis? ( >=dev-python/redis-py-3.2.0[${PYTHON_USEDEP}] )
+	yaml? ( >=dev-python/pyyaml-3.10[${PYTHON_USEDEP}] )"
+# Fix to https://github.com/celery/kombu/issues/474 obliges dev-python/pymongo to >=-3.0.2
+DEPEND="${RDEPEND}
+	>=dev-python/setuptools-20.6.7[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/case-1.5.2[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}] )
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/sphinx_celery-1.1[${PYTHON_USEDEP}] )"
+
+# kazoo is optional for tests.
+# Refrain for now, no established demand for it from users
+
+# Req'd for test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+
+PATCHES=(
+)
+
+python_prepare_all() {
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	rm t/unit/transport/test_etcd.py || die
+	# allow use of new (renamed) msgpack
+	sed -i '/msgpack/d' requirements/extras/msgpack.txt || die
+	# pytest-sugar is not packaged
+	sed -i '/pytest-sugar/d' requirements/test.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# Doc build misses and skips only content re librabbitmq which is not in portage
+	if use doc; then
+		emake -C docs html || die "kombu docs failed installation"
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}