dev-python/kombu: version bump to 4.0.2

Package-Manager: Portage-2.3.3, Repoman-2.3.1

2 files changed, 74 insertions, 0 deletions

diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 83c0e1c72dd6..221e9f562fc6 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1,2 +1,3 @@
 DIST kombu-3.0.34.tar.gz 380374 SHA256 8878ff19b09d86b2689682a4a3eb163d70115ef4ebd974966079a0edd80075da SHA512 9de5d9e4784d814f8c40633bfac08a4e9279d55d2122d1cfdee6418066ba61e0ef7dcaba9cf21d2b0b99989ba292125bbe4b38be90ecc288cb038aea638d1508 WHIRLPOOL d0dfe755af559f4c1d0e8fb6bbe3c7767874a34db57f4958196b853147061e078fac9d5ab31957ab88707220e738a05248afa5d86d9fbdd1a5619aab80d9711a
 DIST kombu-3.0.37.tar.gz 411790 SHA256 e064a00c66b4d1058cd2b0523fb8d98c82c18450244177b6c0f7913016642650 SHA512 ba9bb00e23ce2d3da87eb07aacff8d63ef9879e6ca9f3fe82653cc2ee91610199fe8fc778d7c2e00df05b46130ecda0bdeceda48192b8af1fb0eca41fbb44712 WHIRLPOOL 1e3344eb25024e94d341a3928bd04a9fd13bb41fefd7254e5f2dd70a8b235ae48b93d9b003b21d9ccde4ebdb8d1f349d9af6d54b51c74d6c6b1ee7913ee06919
+DIST kombu-4.0.2.tar.gz 418051 SHA256 d0fc6f2a36610a308f838db4b832dad79a681b516ac1d1a1f9d42edb58cc11a2 SHA512 99be6aa833eedc02897da90ebbd838bf0ac2a21db91350e235fae99ce31607cbc749f73f99d24f76acfc68b81d6263688d35b72ed62bb21d024a3ab385fa666e WHIRLPOOL e140f700c2e00ab892b54664d61c56343fb4d51f65fc0c42e2b4e0b0f75836889f5746061db1f31d3ba5f5981946d47d29ba64b8e6f0561fec054b77167d090e
diff --git a/dev-python/kombu/kombu-4.0.2.ebuild b/dev-python/kombu/kombu-4.0.2.ebuild
new file mode 100644
index 000000000000..e717c4ac3ffb
--- /dev/null
+++ b/dev-python/kombu/kombu-4.0.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="https://pypi.python.org/pypi/kombu https://github.com/celery/kombu"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples msgpack sqs test"
+
+# couchdb backend support possible via dev-python/couchdb-python
+# ditto dev-python/kazoo(>=1.3.1)
+RDEPEND="
+	>=dev-python/py-amqp-2.1.4[${PYTHON_USEDEP}]
+	dev-python/pyro:4[${PYTHON_USEDEP}]
+	sqs? ( >=dev-python/boto-2.13.3[${PYTHON_USEDEP}] )
+	msgpack? ( >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}] )"
+# Fix to https://github.com/celery/kombu/issues/474 obliges dev-python/pymongo to >=-3.0.2
+DEPEND="${RDEPEND}
+	>=dev-python/setuptools-0.7[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/case-1.5.2[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/redis-py-2.10.3[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-3.0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}] )
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/couchdb-python[${PYTHON_USEDEP}]
+		>=dev-python/sphinx_celery-1.1[${PYTHON_USEDEP}] )"
+
+# kazoo is optional for tests.
+# Refrain for now, no established demand for it from users
+
+# Req'd for test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	rm t/unit/transport/test_etcd.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# Doc build misses and skips only content re librabbitmq which is not in portage
+	if use doc; then
+		emake -C docs html || die "kombu docs failed installation"
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}