dev-python/llvmlite: Bump to 0.32.1, permit LLVM 9

Thanks to Aisha Tammy for pointing out that this release actually works
with LLVM 9 even though upstream does not want to officially support
it.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 66 insertions, 0 deletions

diff --git a/dev-python/llvmlite/llvmlite-0.32.1.ebuild b/dev-python/llvmlite/llvmlite-0.32.1.ebuild
new file mode 100644
index 000000000000..a733f9617dcc
--- /dev/null
+++ b/dev-python/llvmlite/llvmlite-0.32.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1 llvm
+
+DESCRIPTION="Python wrapper around the llvm C++ library"
+HOMEPAGE="https://llvmlite.pydata.org/"
+SRC_URI="https://github.com/numba/llvmlite/archive/v${PV/_/}.tar.gz -> ${P/_/}.gh.tar.gz"
+S=${WORKDIR}/${P/_/}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+LLVM_MAX_SLOT=9
+
+RDEPEND="
+	sys-devel/llvm:${LLVM_MAX_SLOT}
+	sys-libs/zlib:0=
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	# test_version hardcodes permitted versions
+	# test_parse* relies on exact error message
+	sed -e 's:test_version:_&:' \
+		-e 's:test_parse_bitcode_error:_&:' \
+		-i llvmlite/tests/test_binding.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_configure_all() {
+	# upstream's build system is just horrible, and they ignored the PR
+	# fixing it, so let's build the shared lib properly using implicit
+	# make rules
+
+	export LDLIBS=$(llvm-config --libs all)
+	export CXXFLAGS="$(llvm-config --cxxflags) -fPIC ${CXXFLAGS}"
+	export LDFLAGS="$(llvm-config --ldflags) ${LDFLAGS}"
+
+	local files=( ffi/*.cpp )
+	emake -f - <<EOF
+ffi/libllvmlite.so: ${files[*]/.cpp/.o}
+	\$(CXX) -shared \$(CXXFLAGS) \$(LDFLAGS) -o \$@ \$^ \$(LDLIBS)
+EOF
+
+	export LLVMLITE_SKIP_LLVM_VERSION_CHECK=1
+}
+
+python_test() {
+	"${EPYTHON}" runtests.py -v || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}