dev-python/pexpect: add 4.8.0_p20230402, enable py3.12

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/pexpect/pexpect-4.8.0_p20230402.ebuild b/dev-python/pexpect/pexpect-4.8.0_p20230402.ebuild
new file mode 100644
index 000000000000..5d6eb118364b
--- /dev/null
+++ b/dev-python/pexpect/pexpect-4.8.0_p20230402.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+COMMIT="2532721644781543ca660e52d48a35bd93872fc1"
+
+DESCRIPTION="Python module for spawning child apps and responding to expected patterns"
+HOMEPAGE="
+	https://pexpect.readthedocs.io/
+	https://pypi.org/project/pexpect/
+	https://github.com/pexpect/pexpect/
+"
+SRC_URI="
+	https://github.com/pexpect/pexpect/archive/${COMMIT}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/ptyprocess-0.5[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc
+
+src_test() {
+	# workaround new readline defaults
+	echo "set enable-bracketed-paste off" > "${T}"/inputrc || die
+	local -x INPUTRC="${T}"/inputrc
+	distutils-r1_src_test
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}