Revert "dev-python/protobuf-python: Remove namespace dep"

This reverts commit 6b8c48a9a4f6604f29785d4951ed0d202fbda1f7.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 71 insertions, 0 deletions

diff --git a/dev-python/protobuf-python/protobuf-python-3.12.4-r1.ebuild b/dev-python/protobuf-python/protobuf-python-3.12.4-r1.ebuild
new file mode 100644
index 000000000000..754ffae59d5e
--- /dev/null
+++ b/dev-python/protobuf-python/protobuf-python-3.12.4-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2008-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{3_6,3_7,3_8,3_9})
+DISTUTILS_USE_SETUPTOOLS="rdepend"
+
+inherit distutils-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/protocolbuffers/protobuf"
+	EGIT_SUBMODULES=()
+fi
+
+DESCRIPTION="Google's Protocol Buffers - Python bindings"
+HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/protocolbuffers/protobuf"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
+fi
+
+LICENSE="BSD"
+SLOT="0/23"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}"
+RDEPEND="${BDEPEND}
+	!<dev-libs/protobuf-3[python(-)]"
+
+S="${WORKDIR}/protobuf-${PV}/python"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
+fi
+
+python_prepare_all() {
+	pushd "${WORKDIR}/protobuf-${PV}" > /dev/null || die
+	eapply "${FILESDIR}/${PN}-3.13.0-google.protobuf.pyext._message.PyUnknownFieldRef.patch"
+	eapply_user
+	popd > /dev/null || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	mydistutilsargs=(--cpp_implementation)
+}
+
+python_compile() {
+	python_is_python3 || local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	find "${D}" -name "*.pth" -type f -delete || die
+}