dev-python/pyatspi: bump to 2.34.0, other tweaks

Fix lack of python optimization all levels with py3.
Update DESCRIPTION.
Support python3.7.

Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/pyatspi/pyatspi-2.34.0.ebuild b/dev-python/pyatspi/pyatspi-2.34.0.ebuild
new file mode 100644
index 000000000000..11642c0a868e
--- /dev/null
+++ b/dev-python/pyatspi/pyatspi-2.34.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Python client bindings for D-Bus AT-SPI"
+HOMEPAGE="https://wiki.gnome.org/Accessibility"
+
+# Note: only some of the tests are GPL-licensed, everything else is LGPL
+LICENSE="LGPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="" # test
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-libs/atk-2.11.2
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
+"
+RDEPEND="${COMMON_DEPEND}
+	>=sys-apps/dbus-1
+	>=app-accessibility/at-spi2-core-2.34[introspection]
+	!<gnome-extra/at-spi-1.32.0-r1
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure --disable-tests
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	installing() {
+		gnome2_src_install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installing
+
+	docinto examples
+	dodoc examples/*.py
+}