dev-python/pygraphviz: Version Bump

Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=554436

Package-Manager: portage-2.2.20.1
Signed-off-by: Justin Lecher <jlec@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/pygraphviz/pygraphviz-1.3.1.ebuild b/dev-python/pygraphviz/pygraphviz-1.3.1.ebuild
new file mode 100644
index 000000000000..376cf2d9dad7
--- /dev/null
+++ b/dev-python/pygraphviz/pygraphviz-1.3.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python wrapper for the Graphviz Agraph data structure"
+HOMEPAGE="http://networkx.lanl.gov/pygraphviz/ https://pypi.python.org/pypi/pygraphviz"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="examples test"
+
+# Note: only C API of graphviz is used, PYTHON_USEDEP unnecessary.
+RDEPEND="media-gfx/graphviz"
+DEPEND="${RDEPEND}
+	dev-lang/swig:0
+	test? (
+		dev-python/doctest-ignore-unicode[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-docs.patch
+	"${FILESDIR}"/${P}-swig-3.patch
+)
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	swig -python pygraphviz/graphviz.i || die
+}
+
+python_test() {
+	PYTHONPATH=${PYTHONPATH}:${BUILD_DIR}/lib/pygraphviz \
+		nosetests -c setup.cfg -x -v || die
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}