dev-python/pyilmbase: bump to version 2.3.0

Remove multilib inherit, python isn't multilib aware
Improve ebuild functions

Closes: https://bugs.gentoo.org/639998
Suggested-by: Jonathan Scruggs <dracwyrm@gentoo.org>
Signed-off-by: Bernd Waibel <waebbl@gmail.com>
Package-Manager: Portage-2.3.49, Repoman-2.3.10
Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 59 insertions, 0 deletions

diff --git a/dev-python/pyilmbase/pyilmbase-2.3.0.ebuild b/dev-python/pyilmbase/pyilmbase-2.3.0.ebuild
new file mode 100644
index 000000000000..fda4c62db801
--- /dev/null
+++ b/dev-python/pyilmbase/pyilmbase-2.3.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="ilmbase Python bindings"
+HOMEPAGE="http://www.openexr.com"
+SRC_URI="https://github.com/openexr/openexr/releases/download/v${PV}/${P}.tar.gz"
+LICENSE="BSD"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+numpy"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEP}
+	>=dev-libs/boost-1.62.0-r1[python(+),${PYTHON_USEDEP}]
+	~media-libs/ilmbase-${PV}:=
+	numpy? ( >=dev-python/numpy-1.10.4 )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEP}
+	>=virtual/pkgconfig-0-r1"
+
+PATCHES=(
+	"${FILESDIR}/${P}-link-pyimath.patch"
+	"${FILESDIR}/${P}-fix-build-system.patch"
+)
+
+DOCS=( README.md )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-boost-include-dir="${EPREFIX}/usr/include/boost"
+		--with-boost-lib-dir="${EPREFIX}/usr/$(get_libdir)"
+		--with-boost-python-libname="boost_python-${EPYTHON:6}"
+		$(use_with numpy)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	# Fails to install with multiple jobs
+	emake DESTDIR="${D}" -j1 install
+
+	einstalldocs
+
+	# package provides pkg-config files
+	find "${D}" -name '*.la' -delete || die
+}