dev-python/rebulk: verbump to 0.8.2

Package-Manager: portage-2.3.3

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/rebulk/rebulk-0.8.2.ebuild b/dev-python/rebulk/rebulk-0.8.2.ebuild
new file mode 100644
index 000000000000..aac7c2b85ef4
--- /dev/null
+++ b/dev-python/rebulk/rebulk-0.8.2.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library that performs advanced searches in strings"
+HOMEPAGE="https://github.com/Toilal/rebulk https://pypi.python.org/pypi/rebulk"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Remove base64-encoded zip archive with pytest.
+	rm runtests.py || die
+
+	# Disable unconditional dependency on dev-python/pytest-runner.
+	sed -i -e "s|'pytest-runner'||g" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}