dev-python/reportlab: Add patch for >=pillow-6

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 66 insertions, 0 deletions

diff --git a/dev-python/reportlab/reportlab-3.5.13-r1.ebuild b/dev-python/reportlab/reportlab-3.5.13-r1.ebuild
new file mode 100644
index 000000000000..77800e21ecca
--- /dev/null
+++ b/dev-python/reportlab/reportlab-3.5.13-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} ) # Tests crash with pypy
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Tools for generating printable PDF documents from any data source"
+HOMEPAGE="http://www.reportlab.com/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz
+	http://www.reportlab.com/ftp/fonts/pfbfer-20070710.zip"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc examples"
+
+RDEPEND="
+	dev-python/pillow[tiff,truetype,jpeg(+),${PYTHON_USEDEP}]
+	media-libs/libart_lgpl
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	app-arch/unzip
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.5.13-disable-network-tests.patch"
+	"${FILESDIR}/${PN}-3.5.13-pillow-VERSION.patch"
+)
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	cd ${P}/src/reportlab/fonts || die
+	unpack pfbfer-20070710.zip
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_compile() {
+	if ! python_is_python3; then
+		local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	pushd tests > /dev/null || die
+	"${PYTHON}" runAll.py || die "Testing failed with ${EPYTHON}"
+	popd > /dev/null || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	if use examples ; then
+		docinto examples
+		dosod -r demos/. tools/pythonpoint/demos
+	fi
+
+	distutils-r1_python_install_all
+}