dev-python/rst-linker: bump to 1.10

setup.py requires pytest 3.5 for testing but 3.4 seems to work, so stick
to that version for now since 3.5 is not yet in the tree.
The whole namespace-package-related logic can be removed since
https://github.com/jaraco/rst.linker/commit/c84284022a198d560e685c5a687458a5be4c5fe6

Package-Manager: Portage-2.3.38, Repoman-2.3.9
Closes: https://github.com/gentoo/gentoo/pull/8625

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/rst-linker/rst-linker-1.10.ebuild b/dev-python/rst-linker/rst-linker-1.10.ebuild
new file mode 100644
index 000000000000..b84ffd335f50
--- /dev/null
+++ b/dev-python/rst-linker/rst-linker-1.10.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} pypy{,3} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Sphinx plugin to add links and timestamps to the changelog"
+HOMEPAGE="https://github.com/jaraco/rst.linker"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/path-py[${PYTHON_USEDEP}]
+		>=dev-python/pytest-3.4[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Ignore the module from ${S}, use the one from ${BUILD_DIR}
+	# Otherwise, ImportMismatchError may occur
+	# https://github.com/gentoo/gentoo/pull/1622#issuecomment-224482396
+	# Override pytest options to skip flake8
+	py.test -v --ignore=rst --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}