proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 70 insertions, 0 deletions

diff --git a/dev-python/scientificpython/scientificpython-2.9.4.ebuild b/dev-python/scientificpython/scientificpython-2.9.4.ebuild
new file mode 100644
index 000000000000..93af0d21a04a
--- /dev/null
+++ b/dev-python/scientificpython/scientificpython-2.9.4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+MY_PN="ScientificPython"
+MY_P="${MY_PN}-${PV}"
+DOWNLOAD_NUMBER=4570
+
+DESCRIPTION="Scientific Module for Python"
+SRC_URI="http://sourcesup.cru.fr/frs/download.php/${DOWNLOAD_NUMBER}/${MY_P}.tar.gz"
+HOMEPAGE="http://sourcesup.cru.fr/projects/scientific-py/"
+
+LICENSE="CeCILL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc mpi test"
+
+RDEPEND="
+	<dev-python/numpy-1.9[${PYTHON_USEDEP}]
+	dev-python/pyro:3[${PYTHON_USEDEP}]
+	sci-libs/netcdf
+	mpi? ( virtual/mpi )"
+DEPEND="${RDEPEND}
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.9-mpi.patch )
+DOCS=( README README.MPI Doc/CHANGELOG Examples/demomodule.c Examples/netcdf_demo.py )
+
+python_prepare_all() {
+	use mpi && PATCHES+=( "${FILESDIR}"/${PN}-2.9.3-mpi-netcdf.patch )
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	if use mpi; then
+		cd Src/MPI || die
+		${PYTHON} compile.py || die
+		mv -f mpipython mpipython-${EPYTHON} || die
+	fi
+}
+
+python_test() {
+	cd "${S}"/Tests || die
+	python_foreach_impl nosetests
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	if use mpi; then
+		cd Src/MPI || die
+		python_newexe mpipython-${EPYTHON} mpipython
+	fi
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( Doc/Reference/. )
+	use mpi && EXAMPLES=( Examples/mpi.py )
+	distutils-r1_python_install_all
+}