dev-python/setuptools: Silence py2 warning

The py2 warning is not very useful for us and its verbosity breaks
other packages.

Closes: https://bugs.gentoo.org/723680
Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/setuptools/setuptools-46.4.0-r1.ebuild b/dev-python/setuptools/setuptools-46.4.0-r1.ebuild
new file mode 100644
index 000000000000..fff9aec03927
--- /dev/null
+++ b/dev-python/setuptools/setuptools-46.4.0-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="https://github.com/pypa/setuptools https://pypi.org/project/setuptools/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	app-arch/unzip
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+		>=dev-python/pytest-3.7.0[${PYTHON_USEDEP}]
+		dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+		dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/futures[${PYTHON_USEDEP}]
+		' -2)
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]"
+
+# Force in-source build because build system modifies sources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DOCS=( {CHANGES,README}.rst docs/{easy_install.txt,pkg_resources.txt,setuptools.txt} )
+
+python_prepare_all() {
+	# silence the py2 warning that is awfully verbose and breaks some
+	# packages by adding unexpected output
+	# (also, we know!)
+	sed -i -e '/py2_warn/d' pkg_resources/__init__.py || die
+
+	# disable tests requiring a network connection
+	rm setuptools/tests/test_packageindex.py || die
+
+	# don't run integration tests
+	rm setuptools/tests/test_integration.py || die
+
+	# xpass-es for me on py3
+	sed -e '/xfail.*710/s:(:(six.PY2, :' \
+		-i setuptools/tests/test_archive_util.py || die
+
+	# avoid pointless dep on flake8
+	sed -i -e 's:--flake8::' pytest.ini || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	distutils_install_for_testing
+	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+	# It tries to sandbox the test in a tempdir
+	HOME="${PWD}" pytest -vv ${PN} || die "Tests failed under ${EPYTHON}"
+}
+
+python_install() {
+	export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
+	distutils-r1_python_install
+}