dev-python/setuptools_trial: Revision bump, adds python 3.7, 3.8

Bump eapi, also duplicate the pkg tests inside our build environment.
metadata.xml take maintainership

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Brian Dolbec <dolsen@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-python/setuptools_trial/setuptools_trial-0.6.0-r1.ebuild b/dev-python/setuptools_trial/setuptools_trial-0.6.0-r1.ebuild
new file mode 100644
index 000000000000..4bc6f905bbc2
--- /dev/null
+++ b/dev-python/setuptools_trial/setuptools_trial-0.6.0-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+DISTUTILS_USE_SETUPTOOLS="rdepend"
+inherit distutils-r1
+
+DESCRIPTION="Setuptools plugin that makes unit tests execute with trial instead of pyunit"
+HOMEPAGE="https://github.com/rutsky/setuptools-trial https://pypi.org/project/setuptools_trial/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="${RDEPEND}"
+
+python_test() {
+	distutils_install_for_testing
+
+	# The pkg test suite creates a virtualenv to install to for testing
+	# The distutils-r1 eclass already does the equivalent for us.
+	# So just run the same commands they do directly...
+	pushd "${S}"/tests/dummy_project > /dev/null || die
+	"${EPYTHON}" -m setup.py trial || \
+			die "trial tests failed with ${EPYTHON}"
+	"${EPYTHON}" -m setup.py trial --reporter=text || \
+			die "trial --reporter tests failed with ${EPYTHON}"
+	popd > /dev/null || die
+	pushd "${S}"/tests/alias_project > /dev/null || die
+	"${EPYTHON}" -m setup.py test || \
+			die "alias_project tests failed with ${EPYTHON}"
+	popd > /dev/null || die
+}