dev-python/sphinxcontrib-qthelp: EAPI 8, PEP517, rm namespace dep

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/sphinxcontrib-qthelp/sphinxcontrib-qthelp-1.0.3-r1.ebuild b/dev-python/sphinxcontrib-qthelp/sphinxcontrib-qthelp-1.0.3-r1.ebuild
new file mode 100644
index 000000000000..a313cb9d28f0
--- /dev/null
+++ b/dev-python/sphinxcontrib-qthelp/sphinxcontrib-qthelp-1.0.3-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Sphinx extension which outputs QtHelp documents"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinxcontrib-qthelp/
+	https://pypi.org/project/sphinxcontrib-qthelp/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+PDEPEND="
+	>=dev-python/sphinx-2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? ( ${PDEPEND} )
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	distutils_write_namespace sphinxcontrib
+	cd "${T}" || die
+	epytest "${S}"/tests
+}