dev-python/theano: version bump 1.0.4

Signed-off-by: Amy Liffey <amynka@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/theano/theano-1.0.4.ebuild b/dev-python/theano/theano-1.0.4.ebuild
new file mode 100644
index 000000000000..645f4a198a38
--- /dev/null
+++ b/dev-python/theano/theano-1.0.4.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Define and optimize multi-dimensional arrays mathematical expressions"
+HOMEPAGE="https://github.com/Theano/Theano"
+SRC_URI="mirror://pypi/theano/${PN^}/${PN^}-${PV}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+	   dev-python/flake8[${PYTHON_USEDEP}]
+	   dev-python/nose[${PYTHON_USEDEP}]
+	   dev-python/parameterized[${PYTHON_USEDEP}]
+	   dev-python/pyflakes[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${PN^}-${PV}"
+
+python_prepare_all() {
+	# remove bundled six
+	find -type f -name "*.py" -exec \
+		 sed -e 's:theano.compat.six:six:g' -i '{}' + || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	distutils_install_for_testing
+	nosetests --verbosity=3 || die
+}
+
+pkg_postinst() {
+	optfeature "Make picture of Theano computation graph" dev-python/pydot-ng
+	optfeature "Required for GPU/CPU code generation" dev-python/pygpu
+}