dev-python/uranium: Version bump to 4.9.1

Closes: https://bugs.gentoo.org/793803
Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Mathy Vanvoorden <mathy@vanvoorden.be>
Signed-off-by: Dennis Lamm <expeditioneer@gentoo.org>

2 files changed, 98 insertions, 0 deletions

diff --git a/dev-python/uranium/Manifest b/dev-python/uranium/Manifest
index 9f84080c85d4..c43cbfb8c6a9 100644
--- a/dev-python/uranium/Manifest
+++ b/dev-python/uranium/Manifest
@@ -1 +1,2 @@
 DIST uranium-4.8.0.tar.gz 1027286 BLAKE2B 5e068255918ca3a6125c308a64d47fab30260aa475505edad2abda664d2c2db7d821d4219ff682d4de90e16de2e36d257410a44f2752c733994739ca160e55b0 SHA512 a2cb923d703e626760c885ceb657566abfa5662f63729fef0b5cdf408da2ed3c23fefcd173b8af529ee79c2384505b2558379b82ba2cfd7a2d2291fe723ddbbd
+DIST uranium-4.9.1.tar.gz 1038046 BLAKE2B 3304e89e0a22fbda0e9e57aaf88f6f11979eb5273d6c8a69f5ec9f050741561f67667a76e2136148808862026e2330f3b5043141ed8d69d255632a8c3c869def SHA512 e665a1ff8ebfc629e4bc2253533a3332d8f8804155432af921ad2e7251d5725daf9346cc5f110595914ac6f0d194db6d7e06dfcd3795b57e35b3d5e6dae594a7
diff --git a/dev-python/uranium/uranium-4.9.1.ebuild b/dev-python/uranium/uranium-4.9.1.ebuild
new file mode 100644
index 000000000000..fa703e3b53ba
--- /dev/null
+++ b/dev-python/uranium/uranium-4.9.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=(python3_{7..9})
+
+inherit cmake distutils-r1
+
+MY_PN="Uranium"
+
+DESCRIPTION="A Python framework for building 3D printing related applications"
+HOMEPAGE="https://github.com/Ultimaker/Uranium"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="debug doc test"
+
+BDEPEND="${PYTHON_DEPS}
+	sys-devel/gettext
+	doc? ( app-doc/doxygen[dot] )
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/mypy[${PYTHON_USEDEP}]
+		')
+	)"
+
+DEPEND="${PYTHON_DEPS}
+	~dev-libs/libarcus-${PV}:=[python,${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/PyQt5[${PYTHON_USEDEP},declarative,network,svg]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		>=dev-python/scipy-1.1[${PYTHON_USEDEP}]
+		sci-libs/shapely[${PYTHON_USEDEP}]
+	')"
+
+RDEPEND="${DEPEND}
+	dev-qt/qtquickcontrols:5
+	dev-qt/qtquickcontrols2:5"
+
+DOCS=( README.md )
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	python_fix_shebang .
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCURA_BINARY_DATA_DIRECTORY:STRING="/usr/share/cura/"
+		-DGETTEXT_MSGINIT_EXECUTABLE="msginit"
+	)
+
+	if ! use debug; then
+		sed -i -e 's logging.DEBUG logging.ERROR g' \
+		 plugins/ConsoleLogger/ConsoleLogger.py \
+		 plugins/FileLogger/FileLogger.py || die
+	fi
+
+	sed -i \
+		-e "s/find_package(PythonInterp 3 REQUIRED/find_package(Python3 ${EPYTHON##python} EXACT REQUIRED COMPONENTS Interpreter/g" \
+		CMakeLists.txt cmake/UraniumPluginInstall.cmake
+
+	sed -i \
+		-e "s/find_package(Python3 REQUIRED/find_package(Python3 ${EPYTHON##python} EXACT REQUIRED/g" \
+		-e 's/set(Python3_EXECUTABLE ${PYTHON_EXECUTABLE})//g' \
+		cmake/UraniumPluginInstall.cmake
+
+	sed -i \
+		-e "s lib\${LIB_SUFFIX}/python\${PYTHON_VERSION_MAJOR}.\${PYTHON_VERSION_MINOR}/site-packages $(python_get_sitedir) g" \
+		-e 's cmake-${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} cmake g' \
+		CMakeLists.txt
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	use doc && cmake_src_compile doc
+}
+
+src_install() {
+	cmake_src_install
+
+	python_optimize "${ED}"/usr
+}