dev-python/weasyprint: bump to v43

Also, re-enable tests.

Signed-off-by: Virgil Dupras <vdupras@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-python/weasyprint/weasyprint-43.ebuild b/dev-python/weasyprint/weasyprint-43.ebuild
new file mode 100644
index 000000000000..d18200b1057c
--- /dev/null
+++ b/dev-python/weasyprint/weasyprint-43.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Visual rendering engine for HTML and CSS that can export to PDF"
+MY_PN="WeasyPrint"
+MY_P="${MY_PN}-${PV}"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+HOMEPAGE="http://weasyprint.org https://github.com/Kozea/WeasyPrint"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="jpeg jpeg2k test tiff"
+
+# Note: specific subslot of pango since it inlines some of pango headers.
+RDEPEND="
+	>=x11-libs/cairo-1.15.4
+	x11-libs/gdk-pixbuf[jpeg?,jpeg2k?,tiff?]
+	x11-libs/pango:0/0
+	>=dev-python/cairocffi-0.9[${PYTHON_USEDEP}]
+	>=dev-python/cffi-0.6:=[${PYTHON_USEDEP}]
+	>=dev-python/cssselect2-0.1[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-0.999999999[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.0[${PYTHON_USEDEP}]
+	>=dev-python/pyphen-0.8[${PYTHON_USEDEP}]
+	>=dev-python/tinycss2-0.5[${PYTHON_USEDEP}]
+	>=media-gfx/cairosvg-1.0.20[${PYTHON_USEDEP}]
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		media-fonts/ahem
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-43-skip-useless-deps.patch"
+	"${FILESDIR}/${PN}-43-skip-failing-test.patch"
+)
+
+S="${WORKDIR}/${MY_P}"
+
+python_test() {
+	pytest -vv || die "testsuite failed under ${EPYTHON}"
+}