dev-python/setuptools: Bump to 63.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 124 insertions, 0 deletions

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index b6fa4849022b..ea895d9d4b32 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -4,3 +4,4 @@ DIST setuptools-62.3.4.tar.gz 2590435 BLAKE2B 089bb185b65107d54b3a17b423caa28b05
 DIST setuptools-62.4.0.tar.gz 2592908 BLAKE2B 5221c32545d451fe9e80f6c78296044fc805e995578f32d2a8809483c00ea84f918a3bb5e1d1a6d184533282d96a68fab8b4d303d839255a640952d1c575f53a SHA512 552bb6c93793a438d8d319b1ef51932e7e15fab965b9fc81a4f15015e02f3e7318b9df9890c3fb59fac1ec443c17cd5cbd17b7227a6a82deb355230673ae9ec5
 DIST setuptools-62.5.0.tar.gz 2596847 BLAKE2B 62bfd0271404dd77fbc1085ce8f6b8977d1f2fd3b1ccf5fc260df8875a2cfab9570db466c29646e7123404d9308765ef6cc6b4524b8c8dd3df9912c11b989e31 SHA512 32a9511ed9b2973cd81641458f8e9172b97d95a7dc10535a670ee1fe2ea3cba27ac9f93909c1d508c83293e6a20ab816bb899aaccf449823b5d67ac98bdf2718
 DIST setuptools-62.6.0.tar.gz 2599326 BLAKE2B 7f4200f9d9e94fca17fad2c37dab6c2175f5562703d2913ac11cf34020e65dd6aa7d024536e5294de5fb5e9523419526f0b56282da62ba0ca40e7e164c97260e SHA512 d67c438d507fc7959162b5e8c2a15e9c36d37e5cd7052e16eeb58d8a9bcf19b725a0e7b840e101500799d725bbc4c1872d0f79eead66a538e891cc7cfbe3d979
+DIST setuptools-63.1.0.tar.gz 2599380 BLAKE2B 532f484ea0e40a820ac266e878e6210c953a37f32f6ec51032c2570395c71fe7d59b30f8787a1127c7c2ebfcd76985bd3f6f57b558f01a34eced8797cc6d1aa6 SHA512 367b52dfbd5d1a6980d061a47c1948ee8efd9632f694c21e8d518639b8097fbda8f1735641c25d7528bc11beeffc42d6bcba9e0d9b755d5b6fbb74d26bf7cc5c
diff --git a/dev-python/setuptools/setuptools-63.1.0.ebuild b/dev-python/setuptools/setuptools-63.1.0.ebuild
new file mode 100644
index 000000000000..4133756fb9e7
--- /dev/null
+++ b/dev-python/setuptools/setuptools-63.1.0.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{8..11} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+SRC_URI="
+	mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.4-r2[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/nspektr-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-4.11.1[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_resources-5.4.0-r3[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	${RDEPEND}
+	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}"/setuptools-62.4.0-py-compile.patch
+	)
+
+	# remove bundled dependencies, setuptools will switch to system deps
+	# automatically
+	rm -r */_vendor || die
+
+	# remove the ugly */extern hack that breaks on unvendored deps
+	rm -r */extern || die
+	find -name '*.py' -exec sed \
+		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+		-i {} + || die
+
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+		setuptools/tests/test_virtualenv.py::test_clean_env_install
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		setuptools/tests/test_extern.py::test_distribution_picklable
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		setuptools/tests/test_editable_install.py::test_editable_with_pyproject
+	)
+
+	epytest -n "$(makeopts_jobs)" setuptools
+}